add s3enum (#4174)

Author: noraj

packages/s3enum/PKGBUILD

@@ -0,0 +1,43 @@
+# This file is part of BlackArch Linux ( https://www.blackarch.org/ ).
+# See COPYING for license details.
+
+pkgname=s3enum
+pkgver=v1.0.0.r9.g498cb74
+pkgrel=1
+pkgdesc='Amazon S3 bucket enumeration.'
+arch=('x86_64' 'aarch64')
+groups=('blackarch' 'blackarch-recon' 'blackarch-scanner')
+url='https://github.com/koenrh/s3enum'
+license=('ISC')
+depends=()
+makedepends=('git' 'go')
+source=("git+https://github.com/koenrh/$pkgname.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd $pkgname
+
+  GOPATH="$srcdir" go mod download
+  GOPATH="$srcdir" go build \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-s -w" \
+    -o $pkgname .
+}
+
+package() {
+  cd $pkgname
+
+  install -Dm 755 $pkgname "$pkgdir/usr/bin/$pkgname"
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
+  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+